【6日でできるVisual Basic2022入門】⑤間違い漢字探しゲーム：コードの実装と実行

「スタート」ボタンのクリック
  ├─ 出題ペアを抽選 → currentWrong/currentRight をセット
  ├─ 16マスをすべて wrong に
  ├─ ランダムな 1 マスだけ right に
  ├─ elapsed=0 → Timer.Start → running=True → 「スタート」ボタンの無効化
  └─ 表示更新（TextHunt, TextTimer）

盤面ボタンクリック（共通ハンドラー）
  ├─ running でなければ無視
  ├─ そのボタンが right？
  │     ├─ Yes: Timer.Stop、running=False、「スタート」ボタンの有効化、記録を表示
  │     └─ No : elapsed += 2.0（ペナルティ）
  └─ TextTimer を 0.00 形式で更新

Timer1.Tick（20ms 推奨）
  ├─ elapsed += Interval/1000.0
  └─ TextTimer 更新（0.00）

Option Strict On
Imports System.Drawing
Imports System.Media

Public Class FormKanjiHunt
    ' ① 出題ペア（wrong：間違いで埋める、right：正解で1マスだけ）
    Private ReadOnly pairs As (wrong As String, right As String)() = {
        (wrong:="糊", right:="湖"),
        (wrong:="話", right:="語"),
        (wrong:="録", right:="緑"),
        (wrong:="潮", right:="朝"),
        (wrong:="倍", right:="培"),
        (wrong:="崎", right:="﨑")
    }

    ' ② ランダムはクラス共通で使い回し
    Private Shared ReadOnly rnd As New Random()

    ' ③ ラウンド状態
    Private currentWrong As String = ""
    Private currentRight As String = ""
    Private elapsed As Double = 0.0
    Private running As Boolean = False

    ' ④ フォーム初期化
    Private Sub FormKanjiHunt_Load(sender As Object, e As EventArgs) _
        Handles MyBase.Load

        ' Enter = Start
        Me.AcceptButton = ButtonStart

        ' 盤面ボタン（Panel2上の Button）に共通ハンドラーを割り当て
        For Each b In SplitContainer1.Panel2.Controls.OfType(Of Button)()
            AddHandler b.Click, AddressOf Buttons_Click
            b.TabStop = False
            b.Text = ""   ' 初回は空
        Next

        ' 表示初期化
        TextHunt.Text = ""
        TextTimer.ReadOnly = True
        TextTimer.Text = "0.00"
    End Sub

    ' ⑤ 「スタート」ボタンのクリック → ラウンド開始
    Private Sub ButtonStart_Click(sender As Object, e As EventArgs) _
        Handles ButtonStart.Click

        ' 出題ペアを抽選
        Dim p = pairs(rnd.Next(pairs.Length))
        currentWrong = p.wrong
        currentRight = p.right

        ' 探す文字を表示
        TextHunt.Text = currentRight

        ' まず全マスを「間違い」で埋める
        Dim cells = SplitContainer1.Panel2.Controls.OfType(Of Button)().ToList()
        For Each b In cells
            b.Text = currentWrong
            b.Enabled = True
            b.BackColor = SystemColors.Control
        Next

        ' ランダムな1マスだけ「正解」にする
        Dim idx = rnd.Next(cells.Count)
        cells(idx).Text = currentRight

        ' タイマー開始
        elapsed = 0.0
        TextTimer.Text = "0.00"
        Timer1.Start()
        running = True

        ' Start は実行中は無効化
        ButtonStart.Enabled = False
    End Sub

    ' ⑥ 盤面ボタン（共通ハンドラー）
    Private Sub Buttons_Click(sender As Object, e As EventArgs)
        If Not running Then Return

        Dim b = DirectCast(sender, Button)

        If b.Text = currentRight Then
            ' 正解：停止して記録表示
            Timer1.Stop()
            running = False
            ButtonStart.Enabled = True
            SystemSounds.Asterisk.Play()
            MessageBox.Show($"正解！タイム：{elapsed:0.00} 秒", "お見事")
        Else
            ' 不正解：+2秒ペナルティ（軽いフィードバック）
            elapsed += 2.0
            b.BackColor = Color.MistyRose
            SystemSounds.Beep.Play()
            TextTimer.Text = elapsed.ToString("0.00")
        End If
    End Sub

    ' ⑦ タイマーで経過表示を更新（Interval=20ms 推奨）
    Private Sub Timer1_Tick(sender As Object, e As EventArgs) _
        Handles Timer1.Tick

        elapsed += Timer1.Interval / 1000.0
        TextTimer.Text = elapsed.ToString("0.00")
    End Sub
End Class

Dim b = DirectCast(sender, Button)